help with bomb

[GANGSTER47]

How I do bomb like in omaha bitch in the allies start ?
without wait when the allies put the bomb
And how I controle the timer of the bomb (how match time left to the bomb to explod)

[Green Beret]

Open the pak5.pk3 then drag out from the obj folder the obj_team3.scr
then open it with notepad or whatever you use.
it has the scripting in there on the timed explosions, Just comment out the
//level waittill roundstart
to test it out

[agentmad007]

Code: Select all

// OMAHA BEACH OBJECTIVE DM
// BY ADAM "SENN" BELLEFEUIL

main:

	level waittill prespawn

	exec global/DMprecache.scr

	thread global/minefield.scr::minefield_setup

	$spawn_allied2 disablespawn
	$spawn_allied3 disablespawn

	$spawn_axis3 disablespawn
	$spawn_axis4 disablespawn

	$bangalore_nopulse_left hide
	$bangalore_nopulse_center hide
	$bangalore_nopulse_right hide

	$world northyaw 270

	$world farplane 7500
	$world farplane_color (0.675 0.663 0.651)

	level.script = maps/obj/obj_team5.scr
	exec global/ambient.scr obj_team5

	setcvar "g_obj_alliedtext1" "- Breach the shingle" 
	setcvar "g_obj_alliedtext2" "- Destroy two 15cm"
	setcvar "g_obj_alliedtext3" "cannons"
	setcvar "g_obj_axistext1" "- Prevent Allies from"
	setcvar "g_obj_axistext2" "taking the beach"
	setcvar "g_obj_axistext3" ""
	setcvar "g_scoreboardpic" "objdm5"

	level waittill spawn

	level.bomb_damage = 200
	level.bomb_explosion_radius = 640
	level.defusing_team = "axis"
	level.planting_team = "allies"
	level.dmrespawning = 1 // 1 or 0
	level.dmroundlimit = 10 // round time limit in minutes
	level.clockside = axis // set to axis, allies, kills, or draw

	level waittill roundstart

	$88mm_explosive1 thread global/obj_dm.scr::bomb_thinker
	$88mm_explosive2 thread global/obj_dm.scr::bomb_thinker

	$88mm_explosive1 thread axis_win_timer
	thread allies_win_bomb $88mm_explosive1 $88mm_explosive2

	thread bomb1_exploded $88mm_explosive1
	thread bomb2_exploded $88mm_explosive2


	thread shingle_setup//This is what you want

end


//*** --------------------------------------------
//*** "Axis Victory"
//*** --------------------------------------------

axis_win_timer:

	level waittill axiswin

end

//*** --------------------------------------------
//*** "Allied Victory"
//*** --------------------------------------------

allies_win_bomb local.bomb1 local.bomb2:

	while (local.bomb1.exploded != 1)
		waitframe

	while (local.bomb2.exploded != 1)
		waitframe
	
	teamwin allies
end


//*** --------------------------------------------
//*** "Bomb 1 Exploded"
//*** --------------------------------------------

bomb1_exploded local.bomb1:

	while (local.bomb1.exploded != 1)

		wait .1

		iprintlnbold "Allies have destroyed the Western Cannon!"

		$spawn_axis2 disablespawn
		$spawn_axis3 enablespawn

end


//*** --------------------------------------------
//*** "Bomb 2 Exploded"
//*** --------------------------------------------

bomb2_exploded local.bomb2:

	while (local.bomb2.exploded != 1)

		wait .1	

		iprintlnbold "Allies have destroyed the Eastern Cannon!"

		$spawn_axis2 disablespawn
		$spawn_axis4 enablespawn

end


//*** --------------------------------------------
//*** "Shingle"
//*** --------------------------------------------

shingle_setup:

	thread shingle_left_start
	thread shingle_center_start
	thread shingle_right_start

end

shingle_left_start:

	$bangalore_trigger_left waittill trigger

	local.player = parm.other

	if (local.player.dmteam != axis)
	{
		goto shingle_left
	}

end

shingle_left:

	$bangalore_left playsound plantbomb1
	$bangalore_left remove
	$bangalore_nopulse_left show

	wait 8
	
	$bangalore_explosion_left1 anim start
	$bangalore_explosion_left2 anim start
	radiusdamage $bangalore_explosion_left2.origin 640 384
	$bangalore_nopulse_left remove
	$barbwire_clip_left remove
	$barbwire_collision_left remove
	$barbwire_left remove
	$spawn_axis1 disablespawn

end

shingle_center_start:

	$bangalore_trigger_center waittill trigger

	local.player = parm.other

	if (local.player.dmteam != axis)
	{
		goto shingle_center
	}

end

shingle_center:

	$bangalore_center playsound plantbomb1
	$bangalore_center remove
	$bangalore_nopulse_center show

	wait 8

	$bangalore_explosion_center1 anim start
	$bangalore_explosion_center2 anim start
	radiusdamage $bangalore_nopulse_center.origin 640 384
	$bangalore_nopulse_center remove
	$barbwire_clip_center remove
	$barbwire_collision_center remove
	$barbwire_center remove
	$spawn_axis1 disablespawn
	$spawn_allied1 disablespawn
	$spawn_allied2 enablespawn

end

shingle_right_start:

	$bangalore_trigger_right waittill trigger

	local.player = parm.other

	if (local.player.dmteam != axis)
	{
		goto shingle_right
	}

end

shingle_right:

	$bangalore_right playsound plantbomb1
	$bangalore_right remove
	$bangalore_nopulse_right show

	wait 8
	
	$bangalore_explosion_right1 anim start
	$bangalore_explosion_right2 anim start
	radiusdamage $bangalore_nopulse_right.origin 640 384
	$bangalore_nopulse_right remove
	$barbwire_clip_right remove
	$barbwire_collision_right remove
	$barbwire_right remove
	$spawn_axis1 disablespawn
	$spawn_axis2 enablespawn
	$spawn_allied1 disablespawn
	$spawn_allied3 enablespawn

end

Look the shingle setup thread , this is the bangalore bombs.

I ve skiped the random bombs scripts to let you have a look at what you want .

Hope this will help you to sort it out. [/code]