.Map :: MoHAA Mapping

Code: Select all

clay_shoot_start:

//----------------------------------------------------\\

//wait for the trigger to be pressed

$clay_trigger waittill trigger

//Animate the switch

$clay_switch playsound alarm_switch

$clay_switch anim turn

//Give the player time to line up shot after pressing switch

wait 3

//launch the clay!

waitthread fire_clay

//Start again!

goto clay_shoot_start 

end

//----------------------------------------------------\\

fire_clay:

//----------------------------------------------------\\

//Spawn the clay

//You can only spawn a model so we are using this bottle

//You can use whatever you want

level.clay = spawn static/bottle_large.tik

level.clay.origin = $clay_target.origin

//Bind the trigger to the target

$clay_target_trigger bind $clay_target

//Bind the clay to the target

level.clay bind $clay_target

//Enable the target trigger

$clay_target_trigger triggerable

for ( local.i = 1; local.i <= 6; local.i++ )

{


//move the clay along the path

//Time is set to 0.5 second between each path origin.

//This is slow and you can use your own speed

$clay_target time 0.5

$clay_target moveto $("clay_path" + local.i)

$clay_target move


wait 0.5

}

//remove the clay

level.clay delete

//Move Trigger back to start place

$clay_target time 0.5

$clay_target moveto $clay_launcher

$clay_target move

wait 1

end

///------------------------------------\\\

clay_hit_thread:

///------------------------------------\\\

$clay_target_trigger nottriggerable


level.clay_ex = spawn animate/fx_explosion_tank.tik

level.clay_ex.origin = $clay_target.origin

level.clay_ex anim start

level.clay delete

waitframe

end