.Map :: MoHAA Mapping

Code: Select all

   (...)

   // find this line
   level waittill spawn

   // add this directly below (example)
   exec global/KC25m/printer.scr

   (...)

Code: Select all

main:

	local.mycvar = KC25m_iprint
	local.space_surrogate = "_" // may NOT be ';'
	local.space = " " // a space

	// loop forever
	while(1)
	{
		local.string = getcvar local.mycvar
		
		// checks if string is not empty
		if(local.string)
		{
			// replace surrogate char with a space
			local.string = waitthread char_replace local.string local.space_surrogate local.space
			
			// print to all players
			waitthread broadcast local.string 0
			
			// clear cvar
			setcvar local.mycvar ""
		}
		
		// need this or it'll crash
		waitframe
	}
	

end

// replaces any chars in string matching find with replace
// find and replace should be single characters
char_replace local.string local.find local.replace:

	// the result
	local.result = ""

	// strings start indexing at 0
	// vectors start indexing at 0
	// arrays  start indexing at 1
	for(local.i = 0; local.i < local.string.size; local.i++)
	{
		// I believe strings are immutable,
		// so making a new string with the result.
		// Might not be necessary to do it this way, though
		local.char = local.string[local.i]
		if(local.char == local.find)
		{
			local.result += local.replace
		}
		else
		{
			local.result += local.char
		}
	}

end local.result

// broadcasts string to all players
// if bold is set to 1, text will print in white clicking text
// if bold is set to 0, text will print in yellow
broadcast local.string local.bold:

	// strings start indexing at 0
	// vectors start indexing at 0
	// arrays  start indexing at 1
	
	// $player is an array of Players
	// $player == $player[1] when there is only 1 player
	for(local.i = 1; local.i <= $player.size; local.i++)
	{
		$player[local.i] iprint local.string local.bold
	}

end