help w/ script

[Krane]

Ok, after 2 days, I were able to "mix" the obj bomb tutorial and jvbots manual to make a bots map. The problem is: the bomb does not make the allies win! and ,after the first round, the game crashes.

here's the frank:

Code: Select all

main:

// set scoreboard messages
setcvar "g_obj_alliedtext1" "Destroy the"
setcvar "g_obj_alliedtext2" "Disc!"
setcvar "g_obj_alliedtext3" ""
setcvar "g_obj_axistext1" "Protect the"
setcvar "g_obj_axistext2" "Disc"
setcvar "g_obj_axistext3" ""

setcvar "g_scoreboardpic" "romestreets_score" 


level waittill prespawn


exec global/DMprecache.scr
exec global/door_locked.scr::lock


//Fog
$world farplane_color "0.2 0.2 0.2"
level.fogplane = 5500 
$world farplane level.fogplane



////////>>>>>>>UBERSOUND<<<<<<<<<<<<<<<<<<<<<<<<

local.master = spawn ScriptMaster 
local.master aliascache fountain sound/amb/Amb_RainPuddle_01.wav soundparms 0.44 0.0 2.5 0.0 370 800 auto loaded maps "obj/romestreets_obj" 

local.master aliascache window_open sound/mechanics/DoorJeepOpen_01.wav soundparms 0.8 0.0 2.5 0.0 200 500 auto loaded maps "obj/romestreets_obj" 

local.master aliascache window_close sound/mechanics/DoorWoodClose_01.wav soundparms 1.0 0.0 1.0 0.0 200 500 auto loaded maps "obj/romestreets_obj" 

local.master aliascache window_open sound/mechanics/DoorJeepOpen_01.wav soundparms 0.6 0.0 2.5 0.0 200 500 auto loaded maps "obj/romestreets_obj" 

local.master aliascache phone_ring sound/mechanics/Mec_PhoneRing_01.wav soundparms 0.4 0.0 1.0 0.0 120 300 auto loaded maps "obj/romestreets_obj" 

local.master aliascache damuber sound/amb/Amb_FireLoop_02.wav soundparms 0.5 0.0 1.7 0.0 177 300 auto loaded maps "obj/romestreets_obj" 

local.master aliascache ambience sound/amb_stereo/Amb_M1_TownExt.mp3 soundparms 1.3 0.0 1.0 0.0 380 800 auto loaded maps "obj/romestreets_obj" 

local.master remove


level waittill spawn

$inferno anim stop

//OBJ STUFF
level.dmrespawning = 0
level.targets_to_destroy = 1
level.clockside = axis
level.dmroundlimit = 5
level.alliesbots = 2
level.axisbots = 4
level.defusing_team = "axis"
level.planting_team = "allies"
level.bomb_damage = 200
level.bomb_explosion_radius = 2048
$panel_bomb thread global/jv_obj_dm.scr::bomb_thinker
waitthread global/jv_bots/jv_mp_ai.scr::enable 0 0 0 0

//Sounds
$speakerphone loopsound phone_ring
$cricketspeaker loopsound ambience
$speaker1 loopsound fountain
$firespeaker loopsound damuber

//WIndow Sound
$romewindow sound_open_start window_open
$romewindow sound_close_start window_close
$romewindow sound_open_end snd_step_paper
$romewindow sound_close_end window_open



//Bar Door
thread trap_door_mover
trap_door_mover:
$trap_door_trigger waittill trigger
$trap_door time 1.2
$trap_door playsound window_open
$trap_door rotateZup 178
$trap_door waitmove
$trap_door playsound door_wood_open_stop
wait 5
$trap_door playsound window_close
$trap_door rotateZdown 178
$trap_door waitmove
$trap_door playsound window_open
goto trap_door_mover

$panel_bomb thread axis_win_timer
thread allies_win_bomb

end

allies_win_bomb:
while(level.targets_destroyed < level.targets_to_destroy)
waitframe
teamwin allies
end

axis_win_timer:
level waittill axiswin
end

[jv_map]

Test results showed out this line:

local.master remove

may cause a server crash. It's best to get rid of it.

Also I don't think your sounds work, since

maps "obj/romestreets_obj"

should be

maps "obj"

Code: Select all

allies_win_bomb:
  while(level.targets_destroyed < level.targets_to_destroy)
    waitframe
  teamwin allies
end

should be

Code: Select all

allies_win_bomb:
  while !($panel_bomb.exploded)
    waitframe
  teamwin allies
end

[Krane]

Thanks, as always, for your help.

The local.master remove line is the last line in your New Ubersound Workaround, isn't it? And yes, the sounds are working perfectly (at least here).

I changed that part in the end of the script. Thanks.

But the bomb didn't make you win, so I took a closer and fresh look to the script and...gotcha!

There is (was hehe) a thread for my bar balcony door that loops to the beggining of the thread again. This way the lines for winning and loose will never come, cauze the script was looping there. So I putted the

$panel_bomb thread axis_win_timer
thread allies_win_bomb

lines ABOVE the Bar Door thread and it's working fine right now.

Solved (I think...)!

Thanks .map & jv_map