.Map :: MoHAA Mapping

Code: Select all

main:

setcvar "sv_screenshot" "off"
setcvar "sv_idcheck" "off"
setcvar "broadcast" ""
level waittill prespawn
thread screenshot
thread array_check
thread mod_showplayers
thread instant_message
level waittill spawn
thread broadcast
end

screenshot:

	local.screenshot = getcvar (sv_screenshot)
	local.message = "Send this screenshot to CONSOLE@WILLYPLACE.COM"
	if ( local.screenshot != "off" )
	{
		$player[local.screenshot] stufftext ("alias screenshot")
		$player[local.screenshot] iprint local.message
		$player[local.screenshot] iprint ("Willyplace Screenshot ID: "+ int (randomfloat 999) )
		wait 1
		$player[local.screenshot] stufftext ("screenshot")
		wait 5	
		setcvar "sv_screenshot" "off"
	}
	waitframe
	goto screenshot
end

array_check:
	local.array_check = getcvar (sv_idcheck)
	
	if ( local.array_check == "1" )
	{
		iprintln "Please pay attention, Console checking id's"
		wait 2
		for ( local.n = 1 ; local.n <= $player.size ; local.n++ )
		{
			$player[local.n] stufftext ("say Console my id is " + local.n)
		}	
		setcvar "sv_idcheck" "off"
	}
	waitframe
	goto array_check
end

mod_showplayers:
	level.gametype = getcvar (g_gametype)
	if ( level.gametype == "1" ) 
	{
		huddraw_align 1 left bottom
		huddraw_rect  1 37 -112 25 25
		huddraw_font  1 facfont-20
		huddraw_color 1 1.0 1.0 1.0
		huddraw_alpha 1 1.0
		huddraw_string 1 ("Players on server : " + $player.size)
	}
	else {

		level.prisal = 0
		level.prisax = 0
		level.as = 0
		level.al = 0
		level.spec = 0
		for ( local.n = 1 ; local.n <= $player.size ; local.n++ ) 
		{ 
			if ( $player[local.n].dmteam == "axis" )
			{
				if ( !isalive $player[local.n] )
				{	
					level.prisax++
				}
				level.as++
			}
			else if ( $player[local.n].dmteam == "allies" )
			{
				if (!isalive $player[local.n] )
				{
					level.prisal++
				}
				level.al++
			}
			else 
			{
				level.spec++
			}
		}
		
		huddraw_shader 1 ("textures/hud/allies")
		huddraw_align 1 left bottom
		huddraw_rect  1 10 -145 25 25
		huddraw_color 1 1.0 1.0 1.0
		huddraw_alpha 1 1.0
	
		huddraw_align 2 left bottom
		huddraw_rect  2 37 -142 25 25
		huddraw_font  2 facfont-20
		huddraw_color 2 0.0 0.0 1.0
		huddraw_alpha 2 1.0
		huddraw_string 2 ("Allies : " + level.prisal + " / " + level.al)
	
		huddraw_shader 3 ("textures/hud/axis")
		huddraw_align 3 left bottom
		huddraw_rect  3 10 -175 25 25
		huddraw_color 3 1.0 1.0 1.0
		huddraw_alpha 3 1.0
	
		huddraw_align 4 left bottom
		huddraw_rect  4 37 -172 25 25
		huddraw_font  4 facfont-20
		huddraw_color 4 1.0 0.0 0.0
		huddraw_alpha 4 1.0
		huddraw_string 4 ("Axis : " + level.prisax + " / " + level.as)
	
		huddraw_align 5 left bottom
		huddraw_rect  5 37 -112 25 25
		huddraw_font  5 facfont-20
		huddraw_color 5 1.0 1.0 1.0
		huddraw_alpha 5 1.0
		huddraw_string 5 ("Spectators : " + level.spec)
	}
	waitframe
	goto mod_showplayers
end

broadcast:
if ( getcvar(nextmap) == "" )
{
	if ( getcvar(mapname) == "obj/obj_team1" )
	{
		setcvar "nextmap" "obj/stlo"
	}
	else if ( getcvar(mapname) == "obj/stlo" )
	{
		setcvar "nextmap" "obj/renan"
	}
	else if ( getcvar(mapname) == "obj/renan" )
	{
		setcvar "nextmap" "obj/obj/lol_v2_13"
	}
	else if ( getcvar(mapname) == "obj/obj/lol_v2_13" )
	{
		setcvar "nextmap" "obj/schplatzburg_obj"
	}
	else if ( getcvar(mapname) == "obj/schplatzburg_obj" )
	{
		setcvar "nextmap" "obj/opcenter_obj"
	}
	else if ( getcvar(mapname) == "obj/opcenter_obj" )
	{
		setcvar "nextmap" "obj/obj_team2"
	}
	else 
	{
		setcvar "nextmap" "obj/obj_team1"
	}
}
	wait 10
	thread t9 "Welcome on willyplace game server"
	wait 30
	thread t9 ("Current map playing: " + getcvar(mapname))
	wait 20	
	thread t9 ("Nextmap: "+ getcvar(nextmap))
	wait 20
	thread t9 ("The maprotation is: " + getcvar(sv_maplist))
	wait 20 
	thread t9 ("Server admins: [WP] WillyC, [WP] Rambo, [WP] DigitaC, [WP](S5) Zwollywood, (S5) Cooldude [WP]")
	wait 20
	thread t9 ("Contact information : [URL] WWW.WILLYPLACE.COM [E-mail] CONSOLE@WILLYPLACE.COM")
	wait 120
end

t9 local.d14:
	huddraw_align 197 center center
	huddraw_rect 197 0 220 640 16
	huddraw_alpha 197 0.45
	huddraw_align 198 center center
	huddraw_color 198 1.0 1.0 1.0
	
	huddraw_font 198 facfont-20
	huddraw_alpha 198 1
	for (local.p=1;local.p<=local.d14.size;local.p++)
	{
		local.d15 = ""
		for (local.o=0;local.o<local.p;local.o++) local.d15 = local.d15 + local.d14[local.o]
		huddraw_rect 198 0 220 635 16
		huddraw_string 198 local.d15
		wait 0.05
	}
	wait 2
	for (local.o=1;local.o<5;local.o++)
	{
		if (local.p==1) 
		{
			huddraw_alpha 198 1
			local.p=0
		}
		else
		{
			huddraw_alpha 198 0
			local.p=1
		}
		wait 0.3
	}
	huddraw_alpha 197 0
	huddraw_alpha 198 0
end

instant_message:
	local.message = getcvar(broadcast)
	if (local.message != "" )
	{
		iprintln local.message
	}
	setcvar "broadcast" ""
	waitframe
	goto instant_message
end