.Map :: MoHAA Mapping

Posted: **Tue May 18, 2004 7:55 pm**

i wanted to have a barking dog sound in my map, but the thing is that I don't have the .wav files for it.
In the script given in the "barking dog tutorial" at this site the sound should be in sound/characters/dog_bark_1.wav (also dog_bark_2, 3, 4 & 5, but i don't have the folder characters. is it somewhere in a pk3 or something?

After this is solved I also want to know if I have my script right.
In the tutorial was said that if you don't have a .scr you should make a new one and if you do just copy/paste the script in to it and that I would probably know where to put what.... but I don't...

This is my script now:
(the thing I'm not sure of = red)

main:

// set scoreboard messages
setcvar "g_obj_alliedtext1" ""
setcvar "g_obj_alliedtext2" ""
setcvar "g_obj_alliedtext3" ""
setcvar "g_obj_axistext1" ""
setcvar "g_obj_axistext2" ""
setcvar "g_obj_axistext3" ""

setcvar "g_scoreboardpic" "none"

local.master = spawn ScriptMaster
local.master aliascache snd_river sound/churchbell/churchbell.wav soundparms 3.0 0.2 1.0 0.2 300 5000 auto loaded maps "obj dm"

level waittill prespawn

exec global/DMprecache.scr
level.script = "maps/dm/church.scr"

level waittill spawn

//Churchbell
churchbell:
$churchbelltrigger waittill trigger
$churchbelltrigger playsound snd_river
goto churchbell
end

local.master = spawn ScriptMaster
local.master aliascache b_1 sound/characters/dog_bark_1.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "
local.master aliascache b_2 sound/characters/dog_bark_2.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "
local.master aliascache b_3 sound/characters/dog_bark_3.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "
local.master aliascache b_4 sound/characters/dog_bark_4.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "
local.master aliascache b_5 sound/characters/dog_bark_5.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "

level waittill spawn

thread dog_bark
end

dog_bark:
//by wacko (woof, woof)
while(1)
{
level.bark_times = randomint 10 + 1
wait (randomint 21 + 30)
for (level.times_barked = 1; level.times_barked <= level.bark_times; level.times_barked++)
{
level.bark_num = randomint 5 + 1
level.bark_style = "b_" + level.bark_num
$bark_o_mat playsound level.bark_style
level.bark_wait = randomfloat 1 + .5
wait level.bark_wait
}
}
end

hope 2 get some help....
thanks

Posted: **Tue May 18, 2004 9:32 pm**

Almost correct but not completely, here:

Code: Select all

main:

	// set scoreboard messages
	setcvar "g_obj_alliedtext1" ""
	setcvar "g_obj_alliedtext2" ""
	setcvar "g_obj_alliedtext3" ""
	setcvar "g_obj_axistext1" ""
	setcvar "g_obj_axistext2" ""
	setcvar "g_obj_axistext3" ""

	setcvar "g_scoreboardpic" "none"
	level.script = "maps/dm/church.scr"
	exec global/DMprecache.scr
	
	local.master = spawn ScriptMaster
	local.master aliascache snd_river sound/churchbell/churchbell.wav soundparms 3.0 0.2 1.0 0.2 300 5000 auto loaded maps "obj dm"
	local.master aliascache b_1 sound/characters/dog_bark_1.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "
	local.master aliascache b_2 sound/characters/dog_bark_2.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "
	local.master aliascache b_3 sound/characters/dog_bark_3.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "
	local.master aliascache b_4 sound/characters/dog_bark_4.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "
	local.master aliascache b_5 sound/characters/dog_bark_5.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "dm "

	level waittill prespawn
	
	level waittill spawn
	
	thread dog_bark
	thread churchbell
end

//Churchbell
churchbell:
	while(1) {
		$churchbelltrigger waittill trigger
		$churchbelltrigger playsound snd_river
	}
end

dog_bark:
	//by wacko (woof, woof)
	while(1) {
		level.bark_times = randomint 10 + 1
		wait (randomint 21 + 30)
		for (level.times_barked = 1; level.times_barked <= level.bark_times; level.times_barked++) {
			level.bark_num = randomint 5 + 1
			level.bark_style = "b_" + level.bark_num
			$bark_o_mat playsound level.bark_style
			level.bark_wait = randomfloat 1 + .5
			wait level.bark_wait
		}
	}
end

Posted: **Tue May 18, 2004 9:35 pm**

The "sound/characters" folder is in "pak3.pk3" and you can unzip it by copying the file and renaming it "pak3.zip". But, you don't need the wav files. The script will find them in the pak file.

Posted: **Tue May 18, 2004 9:41 pm**

He he. I'm so quick

But use tltrude's: he added ambient sounds and nice comments ( and he's a map competition winner, I can't compete with that

)

******* edit ***********
Hey! Stop that tltrude! Your code was way better!

Posted: **Tue May 18, 2004 9:45 pm**

Mine is gone, so fix yours up. Add background sound (mohdm7). That churchbell thing might not work right in a while loop. If it is a trigger_multiple, it will be triggered every .2 seconds.

Posted: **Tue May 18, 2004 9:52 pm**

that was kinda mean T..... take out the code from right underneath poor Bjarne's nose...

Posted: **Tue May 18, 2004 9:56 pm**

Didn't want to confuse the guy with two scripts.

Posted: **Tue May 18, 2004 10:02 pm**

Posted: **Wed May 19, 2004 5:08 pm**

tltrude wrote:Didn't want to confuse the guy with two scripts.

I wish you had... bjarne's script didn't work... I could try yours... altough I don't think it's the script, it's probably me...

I always seem to have problems with those things

Posted: **Wed May 19, 2004 5:13 pm**

i know your problem m8.

Posted: **Thu May 20, 2004 2:57 pm**

Stop adding spam to all the threads, LizardKid! Useless posts, mean people with real poblems don't get an answer as fast, or sometimes, at all.

Stitch - Looks like you have to add a speaker entity targetnamed "bark_o_mat" to the map for it to work. According to the script, your map is named "church".

Code: Select all

main: 

	// set scoreboard messages 
	setcvar "g_obj_alliedtext1" "" 
	setcvar "g_obj_alliedtext2" "" 
	setcvar "g_obj_alliedtext3" "" 
	setcvar "g_obj_axistext1" "" 
	setcvar "g_obj_axistext2" "" 
	setcvar "g_obj_axistext3" "" 

	setcvar "g_scoreboardpic" "" 
    
local.master = spawn ScriptMaster 
local.master aliascache snd_river sound/churchbell/churchbell.wav soundparms 3.0 0.2 1.0 0.2 300 5000 auto loaded maps "m dm obj " 
local.master aliascache b_1 sound/characters/dog_bark_1.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "m dm obj " 
local.master aliascache b_2 sound/characters/dog_bark_2.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "m dm obj " 
local.master aliascache b_3 sound/characters/dog_bark_3.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "m dm obj " 
local.master aliascache b_4 sound/characters/dog_bark_4.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "m dm obj " 
local.master aliascache b_5 sound/characters/dog_bark_5.wav soundparms 1.5 0.0 0.8 0.4 160 4000 voice loaded maps "m dm obj " 

	level waittill prespawn

	exec global/ambient.scr mohdm7 // This line adds backgound wind sounds.

	level.script = "maps/dm/church.scr" 
	exec global/DMprecache.scr  
    
	level waittill spawn 
    
	thread dog_bark 
	thread churchbell
 
end 

//------------------------------
// Churchbell
//------------------------------

churchbell:
 
	$churchbelltrigger waittill trigger 
	$churchbelltrigger playsound snd_river 
	goto churchbell
 
end 

//------------------------------
// Dog bark
//------------------------------

dog_bark: 
 
   while(1) 
{ 
      level.bark_times = randomint 10 + 1 
      wait (randomint 21 + 30) 
	for (level.times_barked = 1; level.times_barked <= level.bark_times; level.times_barked++) 
	{ 
	level.bark_num = randomint 5 + 1 
	level.bark_style = "b_" + level.bark_num 
	$bark_o_mat playsound level.bark_style 
	level.bark_wait = randomfloat 1 + .5 
	wait level.bark_wait 
	} 
} 
end

.Map :: MoHAA Mapping

Dog barking sound

Dog barking sound

characters

gone

code

Re: code

spam