main:
exec global/exploder.scr

// set scoreboard messages
setcvar "g_obj_alliedtext1" "An example of how"
setcvar "g_obj_alliedtext2" "to use the scripts"
setcvar "g_obj_alliedtext3" "for obj maps"
setcvar "g_obj_axistext1" "Just defuse the bomb"
setcvar "g_obj_axistext2" "if you can"
setcvar "g_obj_axistext3" ""

//setcvar "g_scoreboardpic" "mymap"

level waittill prespawn

//*** Precache Dm Stuff
exec global/DMprecache.scr

level.script = maps/obj/exploder_tutorial.scr
exec global/ambient.scr exploder_Tutorial

level waittill spawn

level.defusing_team = "axis"
level.planting_team = "allies"
level.targets_to_destroy = 2 // change this to the number of
// objectives
level.dmrespawning = 1 // 1 or 0 // 1 is respawn 0 is not respawn
level.dmroundlimit = 5 // round time limit in minutes
level.clockside = axis // set to axis, allies, kills, or draw

//level waittill roundstart // comment out to test MP objectives....
$bomb.trigger_name = $trigger2 //trigger name that is used for
// the bomb
$bomb.target.target = $trigger2 //Thing to blow up with the
// bomb
$bomb.target.destroyed_model = "models/statweapons/flak88_d.tik" //destroyed model of thing to
//blow up
$bomb.explosion_fx = "models/emitters/explosion_mine.tik" //explosion FX
$bomb.explosion_sound = "sound/weapons/explo/explo_metalmed1.wav" //explosion sound

$bomb2.trigger_name = $triggerbomb2
$bomb2.target.target = $triggerbomb2
$bomb2.target.destroyed_model = "models/statweapons/flak88_d.tik"
$bomb2.explosion_fx = "models/emitters/explosion_mine.tik"
$bomb2.explosion_sound = "sound/weapons/explo/explo_metalmed1.wav"

$bomb thread global/obj_dm.scr::bomb_thinker
$bomb2 thread global/obj_dm.scr::bomb_thinker

// prefix a $ to access targetnames of objects

$bomb thread axis_win_timer
thread allies_win_bomb

thread bomb1_exploded $bomb
thread bomb2_exploded $bomb2

end // this marks the end of the main thread. All threads below
// this do not execute until called.
explode_my_bomb:
iprintlnbold_noloc "Bomb has been set , 10 seconds to detonation"
wait 2
iprintlnbold_noloc "8"
wait 2
iprintlnbold_noloc "6"
wait 2
iprintlnbold_noloc "4"
wait 1
iprintlnbold_noloc "3"
wait 1
iprintlnbold_noloc "2"
wait 1
iprintlnbold_noloc "1"
wait 1
exec global/exploder.scr::explode 1
iprintlnbold_noloc " The bomb will go off again, but no swapping of models"
end

//*** --------------------------------------------
//*** "Axis Victory"
//*** --------------------------------------------

axis_win_timer:

level waittill axiswin

end

//*** --------------------------------------------
//*** "Allied Victory"
//*** --------------------------------------------

allies_win_bomb:

while(level.targets_destroyed < level.targets_to_destroy)
waitframe

teamwin allies
end

//*** --------------------------------------------
//*** "Bomb 1 Exploded"
//*** --------------------------------------------

bomb1_exploded local.bomb1:

while (local.bomb1.exploded != 1)

wait .1

iprintlnbold_noloc "That's the Eastern Flak88, OK!!!!"

//$spawn_axis2 disablespawn
//$spawn_axis3 enablespawn

end

//*** --------------------------------------------
//*** "Bomb 2 Exploded"
//*** --------------------------------------------

bomb2_exploded local.bomb2:

while (local.bomb2.exploded != 1)

wait .1

iprintlnbold_noloc "That's the Western Flak88....."

//$spawn_axis2 disablespawn
//$spawn_axis4 enablespawn

end